66f8fb52a9
This is related to gdb, and gdb can only work on SH and ifp This was mistakenly kept when app.lds was forked for each SoC Side-effect: fix DEBUG builds when the rockbox binary is expected to be loaded at the start of DRAM and there is no runtime relocation git-svn-id: svn://svn.rockbox.org/rockbox/trunk@28124 a1c6a512-1295-4272-9138-f99709370657
139 lines
2.6 KiB
Text
139 lines
2.6 KiB
Text
#include "config.h"
|
|
|
|
ENTRY(start)
|
|
|
|
OUTPUT_FORMAT(elf32-m68k)
|
|
STARTUP(target/coldfire/crt0.o)
|
|
|
|
#define PLUGINSIZE PLUGIN_BUFFER_SIZE
|
|
#define CODECSIZE CODEC_SIZE
|
|
|
|
#define DRAMSIZE (MEMORYSIZE * 0x100000) - PLUGINSIZE - CODECSIZE
|
|
|
|
#define DRAMORIG 0x31000000
|
|
#define IRAMORIG 0x10000000
|
|
#define IRAMSIZE 0xc000
|
|
|
|
/* End of the audio buffer, where the codec buffer starts */
|
|
#define ENDAUDIOADDR (DRAMORIG + DRAMSIZE)
|
|
|
|
/* Where the codec buffer ends, and the plugin buffer starts */
|
|
#define ENDADDR (ENDAUDIOADDR + CODECSIZE)
|
|
|
|
MEMORY
|
|
{
|
|
DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
|
|
IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
.vectors :
|
|
{
|
|
loadaddress = .;
|
|
_loadaddress = .;
|
|
KEEP(*(.resetvectors));
|
|
*(.resetvectors);
|
|
KEEP(*(.vectors));
|
|
*(.vectors);
|
|
} > DRAM
|
|
|
|
.text :
|
|
{
|
|
. = ALIGN(0x200);
|
|
*(.init.text)
|
|
*(.text*)
|
|
. = ALIGN(0x4);
|
|
} > DRAM
|
|
|
|
.rodata :
|
|
{
|
|
*(.rodata) /* problems without this, dunno why */
|
|
*(.rodata*)
|
|
*(.rodata.str1.1)
|
|
*(.rodata.str1.4)
|
|
. = ALIGN(0x4);
|
|
|
|
/* Pseudo-allocate the copies of the data sections */
|
|
_datacopy = .;
|
|
} > DRAM
|
|
|
|
/* TRICK ALERT! For RAM execution, we put the .data section at the
|
|
same load address as the copy. Thus, we don't waste extra RAM
|
|
when we don't actually need the copy. */
|
|
.data : AT ( _datacopy )
|
|
{
|
|
_datastart = .;
|
|
*(.data*)
|
|
. = ALIGN(0x4);
|
|
_dataend = .;
|
|
} > DRAM
|
|
|
|
/DISCARD/ :
|
|
{
|
|
*(.eh_frame)
|
|
}
|
|
|
|
.iram IRAMORIG :
|
|
{
|
|
_iramstart = .;
|
|
*(.icode)
|
|
*(.irodata)
|
|
*(.idata)
|
|
_iramend = .;
|
|
} > IRAM AT> DRAM
|
|
|
|
_iramcopy = LOADADDR(.iram);
|
|
_noloaddram = LOADADDR(.iram);
|
|
|
|
.ibss (NOLOAD) :
|
|
{
|
|
_iedata = .;
|
|
*(.ibss)
|
|
. = ALIGN(0x4);
|
|
_iend = .;
|
|
} > IRAM
|
|
|
|
.stack (NOLOAD) :
|
|
{
|
|
*(.stack)
|
|
stackbegin = .;
|
|
. += 0x2000;
|
|
stackend = .;
|
|
} > IRAM
|
|
|
|
.bss _noloaddram (NOLOAD) :
|
|
{
|
|
_edata = .;
|
|
*(.bss*)
|
|
*(COMMON)
|
|
. = ALIGN(0x4);
|
|
_end = .;
|
|
} > DRAM
|
|
|
|
.audiobuf (NOLOAD) :
|
|
{
|
|
. = ALIGN(4);
|
|
_audiobuffer = .;
|
|
audiobuffer = .;
|
|
} > DRAM
|
|
|
|
.audiobufend ENDAUDIOADDR (NOLOAD) :
|
|
{
|
|
audiobufend = .;
|
|
_audiobufend = .;
|
|
} > DRAM
|
|
|
|
.codec ENDAUDIOADDR (NOLOAD) :
|
|
{
|
|
codecbuf = .;
|
|
_codecbuf = .;
|
|
}
|
|
|
|
.plugin ENDADDR (NOLOAD) :
|
|
{
|
|
_pluginbuf = .;
|
|
pluginbuf = .;
|
|
}
|
|
}
|
|
|