28d54c6016
git-svn-id: svn://svn.rockbox.org/rockbox/trunk@25725 a1c6a512-1295-4272-9138-f99709370657
81 lines
1.6 KiB
Text
81 lines
1.6 KiB
Text
#include "config.h"
|
|
|
|
ENTRY(start)
|
|
OUTPUT_FORMAT(elf32-m68k)
|
|
STARTUP(target/coldfire/crt0.o)
|
|
|
|
#define DRAMSIZE (MEMORYSIZE * 0x100000)
|
|
|
|
#define DRAMORIG 0x31000000
|
|
#define IRAMORIG 0x10000000
|
|
#define IRAMSIZE 0x18000
|
|
#define FLASHORIG 0x000e0000
|
|
#define FLASHSIZE 0x1f800
|
|
|
|
MEMORY
|
|
{
|
|
DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
|
|
IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
|
|
FLASH : ORIGIN = FLASHORIG, LENGTH = FLASHSIZE
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
.vectors :
|
|
{
|
|
_datacopy = .;
|
|
} > IRAM
|
|
|
|
.data : AT ( _datacopy )
|
|
{
|
|
_datastart = .;
|
|
KEEP(*(.resetvectors));
|
|
*(.resetvectors);
|
|
KEEP(*(.vectors));
|
|
*(.vectors);
|
|
. = ALIGN(0x200);
|
|
*(.icode)
|
|
*(.irodata)
|
|
*(.idata)
|
|
*(.data*)
|
|
. = ALIGN(0x4);
|
|
_dataend = .;
|
|
. = ALIGN(0x10); /* Maintain proper alignment for .text section */
|
|
} > IRAM
|
|
|
|
/* TRICK ALERT! Newer versions of the linker don't allow output sections
|
|
to overlap even if one of them is empty, so advance the location pointer
|
|
"by hand" */
|
|
.text LOADADDR(.data) + SIZEOF(.data) :
|
|
{
|
|
*(.init.text)
|
|
*(.text*)
|
|
. = ALIGN(0x4);
|
|
} > IRAM
|
|
|
|
.rodata :
|
|
{
|
|
*(.rodata*)
|
|
. = ALIGN(0x4);
|
|
_iramcopy = .;
|
|
} > IRAM
|
|
|
|
.stack :
|
|
{
|
|
*(.stack)
|
|
_stackbegin = .;
|
|
stackbegin = .;
|
|
. += 0x2000;
|
|
_stackend = .;
|
|
stackend = .;
|
|
} > IRAM
|
|
|
|
.bss DRAMORIG+0x800000:
|
|
{
|
|
_edata = .;
|
|
*(.ibss)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
_end = .;
|
|
} > DRAM
|
|
}
|